Wimp_WhichIcon on Iconbar

Hi, I’m trying to enumerate the icons on the iconbar. I tried

DIM A% 1024 : SYS "Wimp_WhichIcon", -2, A%, 0, 0 : OSCLI("Memory "+STR$~A%)

but the list is empty (A%!0 = -1). I thought this would work from looking at PRM 3-159; am I doing something wrong, or is there another way to get the icon handles? Thanks.

Hmm… Just had a quick rummage in the Wimp and spotted this:

        CMP     R0,#nullptr2            ; if iconbar,
        BNE     %FT01                   ; check that the task owns this icon

So it may be that you cannot interrogate other icons on the iconbar using Wimp_WhichIcon.

There is, of course, more than one way to flay a feline…

DIM x% 1023
x%!0 = -2
SYS "Wimp_GetWindowInfo",, x%
SYS "XOS_CLI", "Memory "+STR$~(x% + 88)

It’s the iconbar window definition, with its icons following as of +88 in the block.

with its icons following as of +88 in the block

That would be the bit that Nemo was re-arranging to shuffle icons on the bar.

In my WindOpen module, I enumerate the icon bar modules by looping through icon numbers 0 to 255 (hopefully enough), sending wimp message user ack (19) to the icon number on the task bar (window -2), this returns the owning task handle if valid. You can then read the icon infomation Wimp_GetIconState, and get any indirected strings from task memory using Wimp_TransferBlock (if thats used in iconbar icons, I can’t remember).

When I’ve had to do it before, I’ve done exactly the same as druck, iterated through the icons and done a Wimp_GetIconState on them once I know who they belong to.

Great stuff :-)
Druck’s way seems more proper, since it doesn’t look like there’s a way to tell otherwise how much Wimp_GetWindowInfo is going to pour into your block.

   10 REM Name: IconbarKeys
   20 REM Author: Julie Stamp
   30 REM Date: October 2020
   40 REM Purpose: Keyboard control of iconbar
   50 REM License: Apache 2.0
   60 
   70 ON ERROR REPORT : PRINT ERL : END
  140 debug% = FALSE
  150 
  151 DIM x% 1023
  152 x%!0 = -2
  153 SYS "Wimp_GetWindowInfo",,x%
  154 win_block% = x% + 4
  155 num_icons% = win_block%!84
  156 IF debug% THEN PRINT num_icons%
  180 ptr% = win_block% + 88
  190 PROChelp_message
  200 PROCkey_loop
  210 
  220 END
  230 
  240 DEFPROChelp_message
  290   PRINT "Press Z,X to move, Enter to SELECT"
  300 ENDPROC
  310 
  320 DEFPROCselect_icon(i%)
  330   DIM block% LOCAL 19
  340   block%!0 = 0 : REM x
  350   block%!4 = 0 : REM y
  360   block%!8 = 4 : REM buttons S M A
  370   block%!12 = -2
  380   block%!16 = i%
  390   SYS "Wimp_Initialise",200,&4B534154,"Key Test",0 TO ,task_handle%
  400   SYS "Wimp_SendMessage", 6, block%, -2, i%
  410   SYS "Wimp_CloseDown"
  420   END
  430 ENDPROC
  440 
  450 DEFPROCdraw_icon_box(win_block%,icon_block%)
  460   GCOL 3, 255,255,255  : REM EOR
  470   x0% = icon_block%!0 + win_block%!0 : REM Add visible area bl
  480   y0% = icon_block%!4 + win_block%!4
  490   x1% = icon_block%!8 + win_block%!0
  500   y1% = icon_block%!12 + win_block%!4
  510   a% = 24 : REM Correct height
  520   y0% += a%
  530   y1% += a%
  540   IF debug% THEN PRINT x0%,y0%,x1%,y1%
  550   RECTANGLE FILL x0%,y0%,x1%-x0%,y1%-y0%
  560 ENDPROC
  570 
  580 DEFFNmove(min%, current%, max%, move%)
  590   LOCAL new%
  600   new% = current% + move%
  610   IF new% < min% THEN
  620     VDU 7
  630     = min%
  640   ELSE IF new% > max% THEN
  650     VDU 7
  660      = max%
  670   ENDIF
  680 = new%
  700 
  710 DEFPROCkey_loop
  720   current% = 0
  730   PROCdraw_icon_box(win_block%, ptr% + 32*current%)
  740   REPEAT
  750     CASE INKEY 100 OF
  760       WHEN 122,90: REM Z, z
  770                 PROCdraw_icon_box(win_block%, ptr% + 32*current%)
  780                 current% = FNmove(0,current%,num_icons% - 1,-1)
  790                 PROCdraw_icon_box(win_block%, ptr% + 32*current%)
  800       WHEN 120,88: REM X, x
  810                 PROCdraw_icon_box(win_block%, ptr% + 32*current%)
  820                 current% = FNmove(0,current%,num_icons% - 1,+1)
  830                 PROCdraw_icon_box(win_block%, ptr% + 32*current%)
  840       WHEN 13:     REM Enter
  850                 PROCselect_icon(current%)
  860       ENDCASE
  870   UNTIL FALSE
  880 ENDPROC

It doesn’t look like there’s a way to tell otherwise how much Wimp_GetWindowInfo is going to pour into your block.

Usually you’d call it twice: first with bit 0 of R1 set, so that it returns everything apart from the icon definitions, then again with bit 0 clear after you’d allocated a suitably sized block of memory for the data.