Font_ScanString problem

I’ve created a multiline textbox, using Font_ScanString to find the number of characters which will fit in the available space and then breaking on a space or if no space then calling it again without the separator, painting the line and then going again for the remaining bytes in the string.

This is working well when the window is active, but redraws after the window has been obscured are causing some strange behaviour. Specifically Font_ScanString returns a greater value for the number of characters that can be fitted in, despite being given the same inputs, this results in the string being (invisibly) painted beyond the window boundary.

WHILE bytesPlotted% < totalBytes%
	numChars% = 0
	separator% = 32
	PROCget_num_chars_from_width(textPtr%, separator%, widthOS%, numChars%)

	IF numChars% = 0 THEN
		separator% = -1
		PROCget_num_chars_from_width(textPtr%, separator%, widthOS%, numChars%)
		IF numChars% = 0 THEN numChars% = 1
	ENDIF

	SYS "Font_Converttopoints",,xpos%,ypos% TO ,xmil%, ymil%
	SYS "Wimp_SetFontColours",,1,7
	SYS "Font_SetFont",fh%

	fontFlags%=&80
	SYS "Font_Paint",,textPtr%,fontFlags%,xmil%,ymil%,,,numChars%

	ypos% -= 50
	textPtr% += numChars%
	bytesPlotted% += numChars%
ENDWHILE

DEFPROCget_num_chars_from_width(stringPtr%, separator%, widthOS%, RETURN numChars%)
    LOCAL scanFlags%
    scanFlags% = &20
    !scanBlock% = 0
    scanBlock%!4 = 0
    scanBlock%!8 = 0
    scanBlock%!12 = 0
    scanBlock%!16 = separator%   :REM use this character code to split a line on
    scanBlock%!20 = 0
    scanBlock%!24 = 0
    scanBlock%!28 = 0
    scanBlock%!32 = 0
    SYS "Font_Converttopoints",,widthOS% TO ,widthMil%
    *Report fonth%
    *Report stringPtr%
    *Report scanFlags%
    *Report widthMil%
    *Report scanBlock%
    SYS "Font_ScanString",fonth%,stringPtr%,scanFlags%,widthMil%,&7fffffff,scanBlock% TO ,ptr%
    *Report ptr%
    *Report stringPtr%
    numChars% = ptr%-stringPtr%
ENDPROC

Reporter output for a foreground redraw

widthOS%=240
fonth%=10
stringPtr%=57732
scanFlags%=32
widthMil%=96000
scanBlock%=53376
ptr%=57739
stringPtr%=57732
numChars%=7

fonth%=10
stringPtr%=57739
scanFlags%=32
widthMil%=96000
scanBlock%=53376
ptr%=57745
stringPtr%=57739
numChars%=6

Note the two lines of text, one of 7 characters and one of 6 characters. Now for the output from a background redraw:

widthOS%=240
fonth%=10
stringPtr%=57732
scanFlags%=32
widthMil%=96000
scanBlock%=53376
ptr%=57745
stringPtr%=57732
numChars%=13

Exactly the same inputs, but this time it thinks that all 13 characters can be painted in the width available, they can’t :-(

Any ideas? What am I doing wrong!

scanflags% needs bit 8 set for Font_ScanString to use the font handle in R0, otherwise it’s sizing using whatever happens to be current. If you add that, consider using it for Font_Paint as well, supplying the font handle in R0 to save the Font_SetFont calls.

Remember to advance over the space as well if you’ve split on that.

Aside: when using Reporter the output is often clearer if you use
*Report fonth% stringPtr% scanFlags% widthMil% scanBlock%
to list several variables on one line.

Stuart, yes setting bit 8 sorted it. I will also take your suggestion for Font_Paint, thank you.

Martin, I’ve found your Reporter program invaluable, particularly figuring out the different co-ordinate systems, being able to see the values returned in various places has made things a lot easier. Thanks for the tip for getting things listed on a single line.