'Immediate' Echo in Obey

I’ve made an Obey file that copies a bunch of files, and it takes a couple of minutes to run so I’ve tried to put some Echo commands in there to show progress. However, it doesn’t work how I expected.

Instead of displaying each message as it gets to it, it just displays nothing until the script has run to completion, then it displays all the messages at once. Am I missing something simple here or is it more complicated that that?

File is typed Obey and I’m running it in a task window.

Copy commands can’t be interrupted by the task window, and it is likely that any VDU output generated by the echo commands in the task window wont be displayed by the task window handling application before the next copy command starts. If you want to do copies in a task window write a BASIC program which copies the files in reasonable sized chunks, which will allow the task window to interrupt the program, allowing other applications to run including the task window handling application.

I do the same but use TaskObey instead of Obey with no problems for me. Not sure what the difference are.

Thanks for the replies. It seems that it’s not something simple after all.

If you want to do copies in a task window write a BASIC program

I’m just going to leave this in the too-hard basket at this point; the script is just for my own personal use so I’ll just put up with it.

I do the same but use TaskObey instead of Obey with no problems for me. Not sure what the difference are.

TaskObey exhibits the same issue here.

I’m just going to leave this in the too-hard basket at this point

Well, I say that, but then I realised I can just take the existing Obey file, put a star in front of every line, change the echos to PRINTs and then save it as a BASIC file. Seems to work fine.

Thanks for the tip :)

Chris, try this. Save as FileCopy and use as

*FileCopy SourceFile DestinationFile

REM >FileCopy
REM Copy file 1024K at a time
REM Works in taskwindows/obey files and with image fileing system unlike *copy
REM Version 1.00 (03-Apr-1998)
REM Version 1.10 (14-Jun-1999) Added directory creation
REM Version 1.11 (06-Feb-2001) On Error mistake rectified
REM Version 1.12 (01-Mar-2001) OS_File 7 used to create file with load & exec
REM Version 1.13 (26-Sep-2020) Removed printing dots every block
REM (C) 1998 DEEJ Technology PLC
:
ON ERROR PRINTREPORT$;" at ";ERL:END
:
bufsz%=1024*1024
:
PROCinit
I$=FNparam
O$=FNparam
:
DIM buf% bufsz%
:
SYS "OS_File",5,I$ TO obj%,,load%,exec%,size%,attr%
IFobj%=0 ERROR1,"Cant find "+I$
:
IFsize%<bufsz% THEN
 SYS"OS_File",255,I$,buf%,0
 ON ERROR PROCmakedir(O$)
 SYS"OS_File",0,O$,load%,exec%,buf%,buf%+size%
ELSE
 ON ERROR PROCmakedir(O$)
 SYS "OS_File",7,O$,load%,exec%,0,size%
 I%=OPENINI$:IFI%=0 ERROR 2,"Cant open "+I$
 ON ERROR CLOSE#I%:PRINTREPORT$;" at ";ERL:END
 O%=OPENUPO$:IFO%=0 ERROR 3,"Cant open "+O$
 ON ERROR CLOSE#I%:CLOSE#O%:PRINTREPORT$;" at ";ERL:END
 REPEAT
  SYS"OS_GBPB",4,I%,buf%,bufsz% TO ,,,not%
  SYS"OS_GBPB",2,O%,buf%,bufsz%-not%
 UNTILEOF#I%
 CLOSE#I%
 CLOSE#O%
 ON ERROR PRINTREPORT$;" at ";ERL:END
ENDIF
:
END
:
DEFPROCinit
SYS"OS_GetEnv" TO env$
A%=INSTR(env$,CHR$34)
B%=INSTR(MID$(env$,A%+1),CHR$34)
env$=MID$(env$,A%+B%+1)
ENDPROC
:
DEFFNparam
WHILE LEFT$(env$,1)=" ":env$=MID$(env$,2):ENDWHILE
P%=INSTR(env$," ")
IFP%=0 R$=env$:env$="":=R$
R$=LEFT$(env$,P%-1)
env$=MID$(env$,P%)
=R$
:
DEFPROCmakedir(D$)
 ON ERROR PRINTREPORT$;" at ";ERL:END
 LOCAL L%,F%
 L%=LEN(D$)
 REPEAT:L%-=1:UNTILL%=0 OR MID$(D$,L%,1)="."
 IFL%=0 ENDPROC
 D$=LEFT$(D$,L%-1)
 F%=OPENIN(D$)
 IFF%=0 THEN
  PROCmakedir(D$)
  OSCLI("CDIR "+D$)
 ELSE
  CLOSE#F%
 ENDIF
ENDPROC

(Not in relation to Drucks reply) Been away over a year, I recall that you can get better results by running a file with your commands using the Taskwindow command.

Unlike *copy, the BASIC proggy doesn’t seem to preserve the filetype & timestamp.

Unlike *copy, the BASIC proggy doesn’t seem to preserve the filetype & timestamp.

For a number of reasons, I am afraid I did not like druck’s BASIC, so I have just knocked up my own version:

REM>FileCopy
REM Copy file in blocks - with acknowledgments to druck
REM *FileCopy input output [-stamp] [-block <size>]
ON ERROR PROCerror
*ReportClear
SYS"OS_GetEnv" TO envr%
SYS"OS_ReadArgs",",quit,in,out,stamp/s,block/e",envr%,&6000,&2000
SYS"XOS_GenerateError",!&6008 TO I$:REM file to copy from
SYS"XOS_GenerateError",!&600C TO O$:REM name to copy to
stamp%=!&6010:REM stamp file with current datetime
block%=!&6014:IF block% THEN block%=block%!1 ELSE block%=1024*1024
DIM buff% block%-1
i%=INSTR(O$,"."):WHILE i%:REM while 'to' path has directories
 SYS"OS_File",8,LEFT$(O$,i%-1):REM create directory if required
 i%=INSTR(O$,".",i%+1)
ENDWHILE
I%=OPENIN  I$:IF I% ELSE ERROR 1,"Cannot open "+I$
O%=OPENOUT O$:IF O% ELSE ERROR 1,"Cannot open "+O$
REPEAT
 SYS"OS_GBPB",4,I%,buff%,block% TO ,,,rest%
 SYS"OS_GBPB",2,O%,buff%,block%-rest%
UNTIL EOF#I%
CLOSE#I%:I%=0
CLOSE#O%:O%=0
SYS"OS_File",17,I$ TO ,,load%,exec%,,attr%:REM 'from' details
SYS"OS_File",1 ,O$,load%,exec%,,attr%:REM apply to 'to'
IF stamp% THEN SYS"OS_File",9 ,O$:REM stamp if chosen
END
DEFPROCerror
 ON ERROR OFF
 I%=I%:IF I% THEN CLOSE#I%
 O%=O%:IF O% THEN CLOSE#O%
 *ReportError T
END

This does preserve the original attributes, but allows a current time stamp if required. It also allows a choice of block size, with a default to 1M.

This is only briefly tested, so please pull it apart. ;-)

For a number of reasons, I am afraid I did not like druck’s BASIC

Uh oh! Time for a duel. ¹

SYS"XOS_GenerateError",!&6008 TO I$

I know that abuse of SYS is widely used (including by myself!), but ugh, it makes my toes curl…

¹ Chanting mindlessly: two men enter, one man leaves, two men enter, one man leaves, two….

Don’t care, its been working for me for past 24 years.

What have I done?! I go to sleep and then wake to find a BASIC duel!

This is where I repeat my “Seems to work fine” from post #5. If you wish to continue duelling then that’s fine, but please don’t expend too much effort on my account :)