Pinebook RTC

The Pinebook has a ‘real time clock’ based around a 30 bit counter. It is memory mapped at 0×01F00000 with the RTC YY-MM-DD register at offset 0×10. I want to read this register from BASIC but my attempts using OS_Memory (to map 0×01F00000 to 0xFB000000) and *Memory have failed. Can anyone help please?

Can you post the relevant code?

I have tried the following:

   10 REM >ReadTime
   20 
   30 SYS "OS_Memory",14,&01F00000 TO ,,r2%,ref%
   40 OSCLI("Memory "+STR$~(r2%)+" + 10")
   41 SYS "OS_Memory",15,ref%
   42 END
   50 
which produced
>RUN
Address  :     3 2 1 0     7 6 5 4     B A 9 8     F E D C :    ASCII Data
FA500000 :    00004000    00000000    0000000F    00000000 : .@..............
>

A simpler
>PRINT !&1F00000
just produced
Internal error: abort on data transfer at &FC1AF3A0

Hope this helps.

Should that not be:

30 SYS "OS_Memory",14,&FB000000 TO ,,r2%,ref%

Cracked it:

>LIST
   10REM >ReadNow
   20DIM code% 1024
   30code%!256=-1
   40FOR A%=0 TO 2 STEP 2
   50P%=code%
   60[OPT A%
   70SWI "OS_EnterOS"
   80MOV R0, #14
   90MOV R1, #&1F00000 ; RTC memory mapped here
  100SWI "OS_Memory"
  110LDR R0,[R2,#&10]
  120; Read word at offset &10 which contains:
  130; bit 22 = leap year flag
  140; bits 16..21 = year (00..63)
  150; bits 11..8 = month (1..12)
  160; bits 4..0 = day (1..31)
  170STR R0,code%+256
  180MOV R0,#15
  190MOV R1,R3
  200SWI "OS_Memory" ; Map it out again
  210SWI "OS_LeaveOS"
  220MOV PC, R14
  230]
  240NEXT
  250CALL code%
  260yy%=code%!256
  270PRINT "RTC has year=";(yy% AND &3F0000)>>16;" month=";(yy% AND &F00)>>8;" day=";yy% AND &1F
  280IF yy% AND (1<<22) THEN PRINT "Leap year"
  290SYS "OS_Byte",161,128 TO ,,yL%
  300SYS "OS_Byte",161,129 TO ,,yH%
  310PRINT "CMOS year is set to ";yH%*100+yL%
>RUN
RTC has year=23 month=6 day=12
CMOS year is set to 2023
>

Isn’t it August? :)

Congratulations! (What’s the chip type, just out of interest?)

Aren’t both the day and the month wrong? But at least the year is right…

I don’t think it is a chip. It is a 30 bit counter with crystal and backup power. I haven’t connected up to the internet so I think it is doing the ‘last shutdown date’.

There must be something to translate the counter into day/month/year, surely?

I think it may just be part of the SOC.

The problem as presented to me was that a Pinebook would be operating in RISC OS with the right date. It would then be booted into Linux and would show the right date. It would then be booted into RISC OS and think the date was 2053 until and unless it was connected to the internet when it would pick up the right year. Usually RISC OS would be used without connecting to the internet.

I think I have understood what was going on:

I think the problem with the date is that RISC OS and Linux behave differently when faced with a ‘real time clock’ (on the Pinebook) that can only count up to 63 for the year.

Linux dates its files (AIUI) with a datestamp which has a 1 Jan 1970 zero datum. It knows the Pinebook will be obsolete by 2033 and so treats the stored year as an offset from 1970 such that 2023=53. It therefore uses the ‘year’ value directly.

RISC OS dates its files (and stores times internally) with a datestamp which has a 1 Jan 1900 zero datum. It therefore knows the century figure is stored in CMOS RAM, adds that to what it reads as the current year from the real time clock (making 2053, thanks to Linux) and checks it against the whole year figure in CMOS (which is 2023 from the last time set in RISC OS before the latest reboot) takes the later of the two, sets the date again and stores the current year back into CMOS (thus now 2053). Once it can ‘see’ the network it corrects itself (and the CMOS year is set back to 2023 again). Leave it unconnected to the internet and it will continue to think it is 2053.

The following commands will read the stored CMOS year and subtract 30 if the year is between 2050 and 2063. My ‘solution’ is to put these in PreDesk. This seems a rather elegant solution and will last for seventeen years longer (not sure the Pinebook or its user will though). Any comments please?

DIM mem% 1024
SYS "OS_Byte",161,128 TO yL%
SYS "OS_Byte",161,129 TO yH%
IF yH%=20 AND yL%>50 AND yL%<64 THEN
  SYS "OS_Byte",162,128,yL%-30
  SYS "OS_Word",1,mem%
  SYS "Territory_ConvertTimeToOrdinals",-1,mem%,mem%+8
  zz%=mem%!32
  IF zz%>2050 AND zz%<2064 THEN
    zz%-=30
    mem%!32=zz%
    SYS "Territory_ConvertOrdinalsToTime",-1,mem%,mem%+8
    SYS "OS_Word",2,mem%
  ENDIF
ENDIF

Well I suppose it is always best to test that something actually works before thinking you have solved a problem.

At the Bristol user group we all had a go at solving the problem but had had beer and food first and retired hurt!

The BASIC programme below, placed in !Boot.Choices.Boot.PreDesk on the Pinebook should get the year right after Linux has fudged the issue by setting the real time clock (which has only six bits to store the year) to the number of years since 1970 rather than to the right year just omitting the century (which RISC OS expects). Linux will sort itself out once connected to the internet (as RISC OS would do once a WiFi bridge has been set up). At present the use case is that RISC OS cannot see the internet and relies upon the real time clock in the Pinebook. The programme should work OK until 2029 which seems good enough as by 2033 Linux will be setting the real time clock to the year 63 (the highest value 6 bits can store) and will have to do something different as it reaches its own ‘Millenium Bug’ on the Pinebook.

    10 : REM >Tardis6
      20 : DIM mem% 1024
      30 : SYS "OS_Byte",161,128 TO ,,yL%
      40 : SYS "OS_Byte",161,129 TO ,,yH%
      50 : REM PRINT "CMOS year = ";100*yH%+yL%
      60 : IF 100*yH%+yL%>2050 THEN
      70 :   REM Force CMOS year to 202x from e.g. 205x or 206x
      80 :   CASE yL% DIV 10 OF
      90 :   WHEN 5
     100 :     yL%-=30
     110 :     SYS "OS_Byte",162,128,yL%
     120 :   WHEN 6
     130 :     yL%-=40
     140 :     SYS "OS_Byte",162,128,yL%
     150 :   ENDCASE
     160 : ENDIF
     170 : :
     180 : REM Now read RISC OS 5-byte time (GMT)
     190 : !mem%=3
     200 : SYS "OS_Word",14,mem%
     210 : SYS "Territory_ConvertTimeToOrdinals",-1,mem%,mem%+8
     220 : PRINT "Date OSWORD read day=";mem%!24;" month=";mem%!28;" year=";mem%!32
     230 : REM adjust date - I'll test for 205x and 206x and set 202x
     240 : zz%=mem%!32
     250 : CASE zz% DIV 10 OF
     260 : WHEN 205:REM 205x
     270 :   zz%-=30
     271 :   mem%!32=zz%
     290 :   SYS "Territory_ConvertOrdinalsToTime",-1,mem%+1,mem%+8
     300 :   ?mem%=5
     310 :   SYS "OS_Word",15,mem%
     320 : WHEN 206:REM 206x
     330 :   zz%-=40
     340 :   mem%!32=zz%
     350 :   SYS "Territory_ConvertOrdinalsToTime",-1,mem%+1,mem%+8
     360 :   ?mem%=5
     370 :   SYS "OS_Word",15,mem%
     380 : ENDCASE

Is there any sound with the Pinebook Pro?

Yes i am running the latest build that includes sound every thing is progressing well there are a few problems but they are working on them.