How to Compare?

There are several distributions with lots of bundled software. I wanted to compare what is bundled with different machines.

I therefore wanted a listing of the applications on each machine so that a prospective purchaser could see whether a particular piece of software was bundled with the machine chosen.

My method was to examine the SD card using !Cat to produce a ‘DiscCat’ file, which lists every file (including the contents of zip files if SparkFS is running). I then used a short BASIC programme (below) to produce a Draw file itemising the software (i.e. just the application directories) which I printed using the Postscript level 3 drivers and !DrawPrint and then converted to PDF using ps2pdf13.

The result (18 pages of A4) looks like this:

and the BASIC programme to produce it:

      10 : REM >Anal4
      20 : REM This programme reads a DiscCat file and then
      30 : REM creates a Draw file listing each application
      40 : REM on the disc.
      50 : REM First check for MakeDraw and Cat
      60 : mkdrw%=TRUE
      70 : LOCAL ERROR
      80 : ON ERROR LOCAL mkdrw%=FALSE
      90 : IF mkdrw% THEN LIBRARY "<MD$Dir>.MakeDraw"
     100 : RESTORE ERROR
     110 : IF mkdrw%=0 THEN ERROR 10,"<MD$Dir> has not been set to the directory containing MakeDraw - make sure !MakeDraw has been seen by the filer."
     120 : :
     130 : flric%=TRUE
     140 : LOCAL ERROR
     150 : ON ERROR LOCAL flric%=FALSE
     160 : IF flric% THEN P=OPENIN"<Cat$Dir>.Sprites11":sprsz%=10000+EXT#P:CLOSE#P
     170 : RESTORE ERROR
     180 : IF flric%=0 THEN ERROR 10,"Wimp filer icons in Cat not found"
     190 : :
     200 : REM Load Wimp common pool sprites into user area
     210 : DIM usp% sprsz% , kx%(50) , ky%(50) , dirflag%(50)
     220 : DIM smspr% 90 , bufsp% 16000
     230 : REM Small sprite
     240 : !smspr%=&44
     250 : $(smspr%+4)="nameofsprite"
     260 : smspr%!&10=0
     270 : smspr%!&14=1
     280 : smspr%!&18=0
     290 : smspr%!&1C=1
     300 : smspr%!&20=&3C
     310 : smspr%!&24=&3C
     320 : smspr%!&28=&19
     330 : smspr%!&2C=&FFFFFF00
     340 : smspr%!&30=&FFFFFF00
     350 : smspr%!&34=0
     360 : smspr%!&38=0
     370 : smspr%!&3C=0
     380 : smspr%!&40=&1800000
     390 : !usp%=sprsz%+50000000
     400 : usp%!8=16
     410 : SYS "OS_SpriteOp",&109,usp%
     420 : SYS "OS_SpriteOp",&10A,usp%,"<Cat$Dir>.Sprites11"
     430 : REM Enumerate sprite names into an array with their addresses
     440 : DIM sprname$(140) , spradd%(140)
     450 : i%=0
     460 : sp%=usp%+(usp%!8)
     470 : REPEAT
     480 :   spradd%(i%)=sp%
     490 :   sprname$(i%)=FNzterm(sp%+4)
     500 :   i%+=1
     510 :   sp%=sp%+(!sp%)
     520 : UNTIL i%>=(usp%!4)
     530 : ni%=i%
     540 : :
     550 : REM Set up buffer for Draw file
     560 : bufsize%=30000000
     570 : DIM bufmd% bufsize% + 1000
     580 : ddReg%=bufmd%
     590 : PROCmdInitialise(bufsize%, bufmd%)
     600 : PROCmdNoTrace
     610 : PROCmdSetUnits(mdInch%/300)
     620 : PROCmdSetOrigin(0,0)
     630 : font1% = FNmdDefineFont("Homerton.Medium.Oblique")
     640 : PROCmdStartGroup: REM Whole diagram
     650 : PROCmdSetTextStyle(font1%,&EE,&EE,&EE):REM cream bgd
     660 : PROCmdSetTextColour(0,0,0):REM BLACK
     670 : PROCmdSetTextSize(6,6)
     680 : zi%=0
     690 : :
     700 : REM analyse a DiscCat file
     710 : REM Reject any !xxx directories at top level except !Boot
     720 : REM as these will be things I have added
     730 : REM SD card contents will be saved as DiscCat
     740 : P=OPENIN("DiscCat2")
     750 : REM set column widths
     760 : a%=180
     770 : b%=370
     780 : c%=420
     790 : d%=580
     800 : e%=1520
     810 : REM show headings
     820 : PROCmdLine(0,zi%,e%,zi%)
     830 : PROCmdLine(0,zi%,0,zi%-40)
     840 : PROCmdLine(a%,zi%,a%,zi%-40)
     850 : PROCmdLine(b%,zi%,b%,zi%-40)
     860 : PROCmdLine(c%,zi%,c%,zi%-40)
     870 : PROCmdLine(d%,zi%,d%,zi%-40)
     880 : PROCmdLine(e%,zi%,e%,zi%-40)
     890 : PROCmdText(10,zi%-35,"Top directory")
     900 : PROCmdText(a%+10,zi%-35,"App name")
     910 : PROCmdText(c%+10,zi%-35,"Application")
     920 : PROCmdText(d%+10,zi%-35,"Pathname on disc")
     930 : zi%-=40
     940 : REPEAT
     950 :   A$=GET$#P
     960 :   REM read each line and test for containing ".!Run,"
     970 :   i%=INSTR(A$,".!Run,")
     980 :   IF i% THEN
     990 :     j%=1
    1000 :     REPEAT
    1010 :       k%=j%
    1020 :       j%=INSTR(A$,".",k%+1)
    1030 :     UNTIL j%=i%
    1040 :     REM Check it is an app
    1050 :     topdir$=MID$(A$,1,INSTR(A$,".",2))
    1060 :     fulldir$="$"+MID$(A$,1,j%)
    1070 :     dir$=MID$(A$,k%+1,i%-k%-1)
    1080 :     IF ASC(dir$) = ASC("!") AND (LEFT$(topdir$,2)<>".!" OR topdir$=".!Boot.") THEN
    1090 :       REM Look for !Sprites11 , !Sprites22 , !Sprites
    1100 :       PROCmdDiagramInfo(s%,l%)
    1110 :       IF l%>0.9*bufsize% THEN ERROR 10,"Insufficient memory"
    1120 :       R=OPENIN("sdfs::0."+fulldir$+"!Sprites11")
    1130 :       IF R THEN PROCmdSprite(b%+8,zi%-37,"sdfs::0."+fulldir$+"!Sprites11",34,34)
    1140 :       IF R=0 THEN
    1150 :         R=OPENIN("sdfs::0."+fulldir$+"!Sprites22")
    1160 :         IF R THEN PROCmdSprite(b%+8,zi%-37,"sdfs::0."+fulldir$+"!Sprites22",34,34)
    1170 :       ENDIF
    1180 :       IF R=0 THEN
    1190 :         R=OPENIN("sdfs::0."+fulldir$+"!Sprites")
    1200 :         IF R THEN PROCmdSprite(b%+8,zi%-37,"sdfs::0."+fulldir$+"!Sprites",34,34)
    1210 :       ENDIF
    1220 :       IF R=0 THEN
    1230 :         cc$=LEFT$(FNlower(dir$),12)
    1240 :         flag%=0
    1250 :         i%=-1
    1260 :         REPEAT
    1270 :           i%+=1
    1280 :         UNTIL sprname$(i%)=cc$ OR i%+1=ni%
    1290 :         IF sprname$(i%)=cc$ THEN
    1300 :           sp%=spradd%(i%)
    1310 :         ELSE
    1320 :           REM No sprite file try !Boot
    1330 :           OSCLI("IfThere sdfs::0."+fulldir$+"!Boot Then Run sdfs::0."+fulldir$+"!Boot")
    1340 :           REM RMA area
    1350 :           flag%=1
    1360 :           SYS "XWimp_BaseOfSprites" TO ,usp2%
    1370 :           sp%=usp2%+(usp2%!8)
    1380 :           REPEAT
    1390 :             IF FNzterm(sp%+4)<>cc$ THEN sp%=sp%+(!sp%) ELSE flag%=0
    1400 :           UNTIL flag%=0 OR (sp%-usp2%)>=!usp2%
    1410 :           IF flag%=1 AND LEFT$(cc$,1)="!" THEN flag%=0:sp%=spradd%(i%-1):REM generic application sprite
    1420 :         ENDIF
    1430 :         IF (flag% AND 1)=0 THEN
    1440 :           IF (!sp%)<15900 THEN
    1450 :             PROCmdSpriteMem(b%+8,zi%-37,sp%,34,34)
    1460 :           ENDIF
    1470 :         ENDIF
    1480 :       ENDIF
    1490 :       PROCmdLine(0,zi%,e%,zi%)
    1500 :       PROCmdLine(0,zi%,0,zi%-40)
    1510 :       PROCmdLine(a%,zi%,a%,zi%-40)
    1520 :       PROCmdLine(b%,zi%,b%,zi%-40)
    1530 :       PROCmdLine(c%,zi%,c%,zi%-40)
    1540 :       PROCmdLine(d%,zi%,d%,zi%-40)
    1550 :       PROCmdLine(e%,zi%,e%,zi%-40)
    1560 :       PROCmdText(10,zi%-35,topdir$)
    1570 :       PROCmdText(a%+10,zi%-35,dir$)
    1580 :       PROCmdText(c%+10,zi%-35,"Application")
    1590 :       IF LEN(fulldir$)>65 THEN
    1600 :         i%=INSTR(fulldir$,".",LEN(fulldir$)-65)
    1610 :         PROCmdText(d%+10,zi%-35,"... "+MID$(fulldir$,i%))
    1620 :       ELSE
    1630 :         PROCmdText(d%+10,zi%-35,fulldir$)
    1640 :       ENDIF
    1650 :       zi%-=40
    1660 :       IF R THEN CLOSE#R
    1670 :     ENDIF
    1680 :   ENDIF
    1690 : UNTIL EOF#P
    1700 : PROCmdLine(0,zi%,e%,zi%)
    1710 : CLOSE#P
    1720 : PROCmdEndGroup
    1730 : PROCmdSaveDiagram("ListApp")
    1740 : END
    1750 : :
    1760 : DEFFNzterm(p%)
    1770 : LOCAL A$
    1780 : SYS "XOS_GenerateError",p% TO A$
    1790 : =A$
    1800 : :
    1810 : DEFFNlower(Y$)
    1820 : LOCAL x$,x%
    1830 : x$=""
    1840 : WHILE Y$<>""
    1850 :   x%=ASC(Y$)
    1860 :   Y$=MID$(Y$,2)
    1870 :   IF x%>&40 AND x%<&5B THEN x%+=&20
    1880 :   x$+=CHR$(x%)
    1890 : ENDWHILE
    1900 : =x$
    1910 : :

My method was to examine the SD card using !Cat to produce a ‘DiscCat’ file, which lists every file (including the contents of zip files if SparkFS is running). I then used a short BASIC programme (below) to produce a Draw file itemising the software

I’d have thought you would go for the idea of producing a text output file for each distribution, ensure the software is listed without a specific location, and then diff the two files.

I’d have thought you would go for the idea of producing a text output file for each distribution, ensure the software is listed without a specific location, and then diff the two files.

My first thought was simply to find a way of listing what applications were provided on a particular machine so that a prospective purchaser could look to see whether a particular piece of software was included or not. Illustrating it with the application’s sprite seemed a good idea. Looking to see whether a ‘!Sprites’ file was in the appdir and, if not, Filer_Boot on its !Boot file almost worked (a tiny number of apps fall over on the latter). Assuming the datestamp of the app directory would pick up the date of the !RunImage file seemed not to work as I expected – for example:

.!Boot.Choices.Boot.Tasks.!CPUCLoad,FFFFFF55,477A1E20,Directory
.!Boot.Choices.Boot.Tasks.!CPUCLoad.!RunImage,FFFFF859,D2847409

&55477A1E20 = 13:34 25-Jan-2016 (the date the directory was created)
&59D2847409 = 23:10:51 01-Apr-2022 (the date of the !RunImage file)

so the filer must do that bit of magic itself. Until I saw how many apps were listed, I was going to write a short bit of text for each saying what it does. Instead I decided to show its version date but I need to get that from its !RunImage file or if not present, its !Run file directly rather than from the app directory datestamp. Another version!

I’d have thought you would go for the idea of producing a text output file for each distribution

The programme now produces csv outout as well as Draw. Comparing the software bundled with the Raspberry Pi SD card image for RISC OS 5.24 and 5.28 gives a rather simpler picture:

Comparing files AppList24t.csv and APPLIST28T.CSV
***** AppList24t.csv
    1:  RISC OS 5.24 Image on SDFS::0,
  127:  !NutPi,.Utilities.!NutPi.
***** APPLIST28T.CSV
    1:  RISC OS 5.28 Image on SDFS::0,
   53:  !DPlngScan,.Utilities.!DPlngScan.
   66:  !ePic,.Utilities.!ePic.
  164:  !Python27,.Programming.Python.!Python27.
*****