Scroll bars and window icons

Hi,

I have a question. I suspect the answer is no, but I am always hopeful. Is it possible to increase the size of window icons without having to lower the screen resolution? I specifically mean the ones that are part of the window not the program running, Back, Close etc. I’m finding it harder to get the mouse on target as I get older.

Cheers,
Becky.

I think I saw a large-icons theme for one version of RISC OS, although I’m not entirely sure which – sounds the kind of thing that might have been in Adjust. It is possible the RISC OS 5 theme manager allows this.

If you wanted to experiment, look at one of the existing themes to see if it has a Sprites11. These will be 180dpi double-size icons. Use David Pilling’s Scan Software to change the dpi setting of each sprite from 180 to 90 dpi (on the toolbar) and re-save. I think this should give you double-size, normal 90dpi sprites. Save each into a theme, and see if it works.

There isn’t, as far as I am aware, any automated method.

The other tip is to consider if you can fit in a bigger monitor/tv. You can, for example, get 27" 1080p displays rather than the typical 23/24" monitors (or even 32" 1080p I think). These will keep the pixel count (resolution) the same, whilst making on-screen elements larger. For example, I run a (fairly affordable) 32" 2560×1440 display, because I find the more common 27" versions a touch small.

I just created double sized cicon22 and sicon22.

Thank you both for the replies. I went with David’s suggestion.

Cheers,
Becky.

David Pilling’s Scan Software

That’s a good idea. DPlingScan, from the PlingStore, can be used to upscale the toolsprites. (Tested exactly once here.)

I will have a look at DPlingScan. Just doubling the size gave me a quick fix. If I do all the other window sprites that will tidy it up. Maybe I’ll even mess about with them. :)

Cheers,
Becky.

…dare I say, Paint can do it, and cope with multiple sprites in a file. Menu → Edit → Scale X or Scale Y

…dare I say, Paint can do it, and cope with multiple sprites in a file. Menu → Edit → Scale X or Scale Y

Except that’s not what Andrew said. He said

…change the dpi setting of each sprite from 180 to 90 dpi…

which, as far as I’m aware, can’t be done by Paint. The only tool that I’m aware of which can do it is DPlngScan.

I’m happy to be corrected on this, as it’s a pain to need to find third-party software to fettle !Sprites11 files that the OS supports natively.

which, as far as I’m aware, can’t be done by Paint. The only tool that I’m aware of which can do it is DPlngScan.

ChangeFSI can do it too, somehow. I seem to recall that it’s a bit fiddly though!

The reason I suggested using Sprites11 as a base is that the 180dpi sprites are basically double the pixel count already (ie. double size, double detail). They appear “normal” size because of the double-dpi setting. Once set to 90dpi in the manner I described (and there may be other routes – that’s just how I do it) they will appear as double size, but with all the detail preserved.

It just seemed like a good way to get nice-looking double-sized icons without having to manually scale things which could look a bit “yuck” and, yes, I’d forgotten you could use the “scale” option in !Paint because I tend not to use that scaling for the “yuck” reason.

Longer term, one might want to start with the double size icons and scale them down to (say) 60-75% of original size to get 120-150% sized icons, which might look less wildly-disproportionate when used for real. ChangeFSI would be my weapon of choice for that, once the dpi was set to 90dpi.

Incidentally, if Rebecca does succeed with any of these approaches to create a theme that works for her, may I suggest posting a link on the forum and/or submitting to ROOL as I think other people might benefit from accessibility aids such as this. None of us are getting any younger, and many of us will need a bit of extra help interacting with our computers as the year pass.

may I suggest posting a link on the forum and/or submitting to ROOL as I think other people might benefit from accessibility aids such as this.

IMHO that is a very good suggestion.

As a side note: For my DME Theme Manager, it does support multiple icon’s size for the same theme as a selection menu (this might be also a suggestion for ROOL to improve their Theme Manager).

I am figuring out what would be the best way to name the menu’s options (aka would DPI or just pixel’s size be better?). The menu is obviously dynamic (aka if a theme does NOT have scaled icons, then it’ll display only “standard size” selectable).

name the menu’s options

big, bigger, double-size ?

and many of us will need a bit of extra help interacting with our computers as the year pass.

Am I the only one who has noticed that the eff-off button on Android full screen adverts keeps getting smaller? Also, they’ve made it so you have to tap exactly upon it, otherwise your “near but not near enough” tap is interpreted as “yes I want to know more about this [REDACTED]”.

benefit from accessibility aids

This is one of the wins that Windows has over RISC OS. Back in the Win3 days, it wasn’t uncommon to come across a PC with no mouse, so Windows had full keyboard support.

Ever since the first Archimedes, a mouse was standard so no need for key controls, which is a shame as they can be very helpful ¹. Alt-F4 to choose an app when you’re done with it, Alt-Tab to switch to a different app (there’s a module that does this on RISC OS), and keyboard control of menus. As screen resolutions get bigger and the comparative size of menus get smaller, as do the necessary manipulations to use the menus.

¹ Keyboard keyboard keyboard STOP find mouse grab it locate pointer move click STOP keyboard keyboard keyboard … I find the two mental context switches indicated by STOP ² to be extremely expensive. I greatly appreciate things that have keyboard shortcuts; you should be able to ^ShB to toggle bold. If you have to stop and click an icon, that’s just wrong. Leave that nonsense to people that call themselves “managers”.

² PEOPLE OF A CERTAIN AGE WILL REMEMBER WHEN TEXT MESSAGES USED TO END WITH STOP

I would have thought that !ConvImgs would be able to do this too on a group of images — it appears to do most of the same conversions that DPingScan can do, and was originally from the same stable.

big, bigger, double-size ?

Thanks Stuart, if it works for everyone, I am good with it. As a side note, Linux (for the mouse pointer) tends to use the pixels area size.

The way the DME “publish” this setting (right now), is set an ENV variable: DesktopIconsSize$DME (after the user has selected the option and if the option is available in the selected theme). Obviously the setting happens also at load time (if it was previously stored).

So, if there are better naming conventions for this please let me know. I am fighting to get a unified Config protocol at the moment, so it will take a while before it’s ready for early beta testing.

If it’s of interest, I can open another topic where to discuss more of the elements it will introduce.

Aw, man, super chunky!!!! :) :)

REM >toolfudge
REM
REM By Rick Murray, 17th April 2024
REM
REM For Becky, 'cos sometimes it's easier just to write code. :)

ON ERROR PRINT REPORT$+" at "+STR$(ERL) : END

REM Change this as desired; DON'T USE A PATH VAR, we use this to save
toolsprites$ = "$.!Boot.Resources.!ThemeDefs.Themes.Raspberry.Tools"

REM How big is the file?
SYS "OS_File", 23, toolsprites$ TO ,,,,len%,,type%
IF (type% <> &FF9) ERROR 17, "Not a sprite file!"


REM Initialise sprite area and load sprites
len% += 4
DIM spr% len%
spr%!0 = len%
spr%!8 = 16
SYS "OS_SpriteOp", (256 + 9), spr%
SYS "OS_SpriteOp", (256 + 10), spr%, toolsprites$

REM How many sprites?
SYS "OS_SpriteOp", (256 + 8), spr% TO ,,,scount%


REM For reading the name
DIM name% 16 : REM Needs 12, but allow for adding termiluff


REM Pass one - rename all of the *22 to __*22
REM            (for later deletion)
FOR loop% = 1 TO scount%
  REM Read the name
  SYS &2E, (256 + 13), spr%, name%, 16, loop% TO ,,,nl%
  name%?nl% = 13
  IF (RIGHT$($name%, 2) = "22") THEN
    newname$ = "__"+$name%
    SYS "OS_SpriteOp", (256 + 26), spr%, name%, newname$
  ENDIF
NEXT


REM Pass two - look for *11 ones and fiddle the DPI;
REM then rename them as *11 -> *22
FOR loop% = 1 TO scount%
  REM Read the name
  SYS &2E, (256 + 13), spr%, name%, 16, loop% TO ,,,nl%
  name%?nl% = 13
  IF (RIGHT$($name%, 2) = "11") THEN
    REM Get the sprite address
    SYS "OS_SpriteOp", (256 + 24), spr%, name% TO ,,addr%

    REM Read the sprite mode
    mode% = addr%!40

    REM It should be something like &202D0169
    REM Bits 27-31 are a mode type
    REM If bits 27-31 are non-zero, then:
    REM   Bits 14-26 = V DPI
    REM   Bits  1-13 = H DPI
    REM   Bit      0 = Set

    IF ( ( mode% >> 27 ) <> 0 ) THEN
      IF ( ( ( mode% >> 1 ) AND 4095 ) = 180 ) THEN
        REM Okay, it's something with H DPI of 180,
        REM that's good enough for us to proceed.

        REM Keep mode and ID bit
        mode% = mode% AND &F8000001

        REM Fudge in 90 dpi
        mode% = mode% + (90 << 1) + (90 << 14)

        REM And paste it back
        addr%!40 = mode%

        REM Now rename this sprite
        newname$ = LEFT$($name%, LEN($name%) - 2)+"22"
        SYS &2E, (256 + 26), spr%, name%, newname$
      ENDIF
    ENDIF
  ENDIF
NEXT


REM Pass three - get rid of the unnecessary sprites
REM Scan backwards 'cos we're deleting things
FOR loop% = scount% TO 1 STEP -1
  SYS &2E, (256 + 13), spr%, name%, 16, loop% TO ,,,nl%
  name%?nl% = 13
  IF (LEFT$($name%, 2) = "__") THEN
    REM Nukage!
    SYS "OS_SpriteOp", (256 + 25), spr%, name%
  ENDIF
NEXT


REM Save the spritefile
SYS "OS_SpriteOp", (256 + 12), spr%, toolsprites$+"Fudged"


REM Done!
END

Have fun!

…for poops and giggles… (I did this so you don’t have to)

Edit: Astonishingly, it is possible to turn this up to eleven and make it all twice as big as pictured above.

Paint can do it, and cope with multiple sprites in a file.

Just for the record – DPlngScan has always been able to load and edit sprite files with multiple sprites contained within them.

Changing the dpi of an image in DPScan is trivial, although for sprites you need to stick with values of e.g. 90, 180 etc. With some other image formats the dpi can be set to arbitrary values.

Am I the only one who has noticed that the eff-off button on Android full screen adverts keeps getting smaller?

Meanwhile, scroll bars seem to be shrinking on other platforms. The Mac version of Discord has a left panel listing the various “channels”, and the mouse target is an absurd two pixels wide (the actual graphic is a bit wider, but only two pixels respond to the mouse).

Am I the only one who has noticed that the eff-off button on Android full screen adverts keeps getting smaller? Also, they’ve made it so you have to tap exactly upon it, otherwise your “near but not near enough” tap is interpreted as “yes I want to know more about this [REDACTED]”.

I have an iPhone, supplied by work for work purposes, it suffers the same way with adverts. I find that unless filtered out, these things make much of the news media unusable.

Astonishingly, it is possible to turn this up to eleven and make it all twice as big as pictured above.

It’s a web page, sizes are scaled. Your big is no doubt much bigger at Clive’s residence.
Just wondering how it would look on the wall mounted display in one of the training rooms, or even the clinical review rooms (bigger than humans)

Thanks again for the comments and suggestions. A few things to look at. I’m going to have a play with Rick’s program later.

Later: I love it, thanks Rick.

Cheers,
Becky.

Just wondering how it would look on the wall mounted display in one of the training rooms, or even the clinical review rooms (bigger than humans)

Here you go.

What happens if you increase the Wimp font size too?

Meanwhile, scroll bars seem to be shrinking on other platforms.

And, my pet hate, being invisible until you wave the mouse over exactly the right area. You’d have thought that these big software houses (looking at you, Microsoft) would employ some experts in Human Computer Interaction.

Another obvious fail is the way some interfaces (e.g. Onedrive in Teams) update the list of recent files just before you click on something that was already there, meaning you end up clicking on completely the wrong thing. They should just refuse to accept any clicks for half a second after updating the list to deal with the eye-brain-nerve-finger latency inherent in the human hardware.