SWI Socket_Connect

I am writing some routines in Basic to communicate from one Pi to another using TCP/IP.

I have the ‘receive’ side working without needing EasySockets. I am using code based on Stuart Brodie’s !HTTPServr from 1996. His code serves as a very useful guide to using the socket SWIs in Basic.

However, I am having trouble with the ‘send’ side as I can not find any documentation for the Socket_Connect SWI. As I am writing in basic, I need the information in the same style in which all of the other SWIs are documented in the PRMs.

Does anyone know of socket documentation in such a format, as I can not convert the info I have found for programs written in ‘C’. Alternatively, an example of somes lines of Basic code would be very useful.

I think that once I have a connection established, then I should be OK with the rest.

Does anyone know of socket documentation in such a format, as I can not convert the info I have found for programs written in ‘C’. Alternatively, an example of somes lines of Basic code would be very useful.

Have a peek at AntiSpam the uncompressed source BASIC is in the package – it’s the “Source” file in !AntiSpam.Resources.

I was going to point you to the PRMs on ROL’s web site, but it seems the Socket documentation there also assumes C.

However, StrongHelp comes to the rescue! Download the InetSocket manual from http://www.riscos.info/downloads/stronghelp/manuals/inetsocket106.zip and I suspect the info you need will be in there.

Thank You both. I have now got a bit of reading to do!

EDIT – 1 hour later – Six lines of basic in a task window and I now have simple one line messages being sent from one Pi to another.

Having both sets of information made it all fit together very nicely. :)

John, please would you share your BASIC code?
I’ve been looking for a simple introduction to sockets, but never really got anywhere.

Same here… would be a good candidate for the BBC Basic contest :)
https://www.riscosopen.org/forum/forums/1/topics/3042

Thank You both. I have now got a bit of reading to do

I recommended AntiSpam as a source of example code as pretty much everything I’ve forgotten¹ about socket coding came from the early versions of AntiSpam or the PRMs and mostly from AntiSpam.

1 hour later – Six lines of basic in a task window and I now have simple one line messages being sent from one Pi to another

I’m impressed with the 1 hour bit, as I recall it took me a whole weekend to get working code doing DNS queries.

¹ A few years back, probably close to 10

The 1 Hour was just to get a simple socket connection to another Pi on my local network. DNS is a whole new exercise.

My six lines of code for my test assumed that I had software (on port 9003) at the receiving end (IP address 10.0.128.116) to deal with the incoming data. The six lines were:

110 DIM address% 16, data% 32: $data%="test:3534510940753996;": port%=9003
120 SYS "Socket_Creat",2,1,0 TO socket%
130 !address%=2: address%?2=port%>>8: address%?3=port%
140 address%?4=10: address%?5=0: address%?6=128: address%?7=116: REM IP=10.0.128.116
150 address%!8=0: address%!12=0: SYS "Socket_Connect",socket%,address%,16
160 SYS "Socket_Send", socket%,data%, LEN$data%:  SYS "Socket_Close", socket%

If you have access to the raw access logs on a local web server then the following code can be verified by looking at the web server access log. It will generate a 404 error if the cgi script does not exist.

 10 REM Simple Web Server Request
 20
 30 DIM address% 16:              REM 16 byte buffer for Address of remote host
 40 DIM data%    32:              REM 32 byte buffer for data send to remote host
 50 port%=80:                     REM In this case remote host is a web server
 60 $data%="GET /cgi-bin/demo":   REM Web server should run the script
 70
 80 REM Now create the socket
 90 SYS "Socket_Creat",2,1,0 TO socket%:    REM See StrongHelp for explanation
100
110 REM Set up the Address buffer:          REM Again StrongHelp gives more details
120 !address%=2:                            REM We want a TCP connection
130 address%?2=port%>>8: address%?3=port%:  REM Bytes 2 and 3 are set to the port number
140 address%?4=10: address%?5=0: address%?6=128: address%?7=201:    REM IP = 10.0.128.201
150 address%!8=0: address%!12=0:            REM These words have to be zero
160
170 REM Now Connect to the remote Socket    Will Block until connection completes
180 SYS "Socket_Connect",socket%,address%,16
190
200 REM Send Data to Remote Socket          In our case a simple web request
210 SYS "Socket_Send", socket%,data%, LEN$data%
220
230 REM We will not wait for any response - as we have no code yet to deal with it!
240 SYS "Socket_Close", socket%:            REM Socket now closed
250 END

Hope to see code to get content of a webpage. The beginning of a very cool code to make apps based on web services.
I would love to get the equivalent of this: http://weboob.org/modules