RPI 3 and GPIO Module

I did start with a Raspberry Pi B+ and the GPIO module from Tank, that worked very nice. Of course I had to buy a Raspberry Pi 2 and tried the GPIO module again, worked ok too.
Than came the Raspberry Pi 3 and I had to have that one also of course. Finally I got RISCOSPi working with the ROM V5.23.
On my RPi 2 i am also using RISCOS with ROM V5.23 because of the Raspberry TouchScreen, and the GPIO module works fine.
But now starts the tears, the GPIO module doesn’t work on the Raspberry Pi 3.
With GPIOMachine i get the message: We are running on machine not detected.

Does the GPIO module not work on the RPI 3?

DavidS
I just downloaded the latest version from the site from tank V 0.60, this version works on my RPi 2.

There is source available and is tagged as version 0.63.

Have we got any further with this?
I’ve got a project that needs to use the GPIO on a RPi3, and my programming doesn’t go much further than BBC BASIC (on RISC OS, that is).

The same project is also requiring to send/receive over the serial port…but that’s a subject for another thread.

The GPIO module is being updated to work on all models of Pi, including A+, Pi3, Zero and Compute Module. The Pico update is imminent (as of the London show) and RC15 is a few weeks away (as of the London show). The Serial module is now in ROM, so should ‘just work’. Example code for each:

Push button switch connected between GPIO 24 (pin 18 on header) and GND (pin 20 on header) with a 220R resistor connected between GPIO 24 and 3.3V (pin 17 on header). LED connected with a 68R resistor in series between GND and GPIO 10 (pin 19 on header)

   10 REM >GPIO_Test
   20 REM
   30 gpio%=TRUE
   40 LOCAL ERROR
   50 ON ERROR LOCAL gpio%=FALSE
   60 IF gpio% THEN *RMEnsure GPIO 1.00 Error GPIO Module not present
   70 RESTORE ERROR
   80 IF gpio% THEN
   90   SYS "GPIO_Info" TO low%,high%,list%
  100   PRINT "Lowest=";low%;" highest=";high%
  110   :
  120   REM Set pin 10 TO OUTPUT LOW
  130   REM Set pin 24 to INPUT
  140   SYS "GPIO_ReadOE",10 TO pin10%
  150   IF pin10%=0 THEN PRINT "Pin 10 is currently an output"
  160   IF pin10%=1 THEN PRINT "Pin 10 is currently an input"
  170   SYS "GPIO_ReadOE",24 TO pin24%
  180   IF pin24%=0 THEN PRINT "Pin 24 is currently an output"
  190   IF pin24%=1 THEN PRINT "Pin 24 is currently an input"
  200   SYS "GPIO_WriteData",10,0
  210   SYS "GPIO_WriteOE",10,0
  220   SYS "GPIO_WriteOE",24,1
  230   PRINT "Hold SPACE bar to light LED, push button"
  240   REPEAT
  250     SYS "GPIO_ReadData",24 TO pin24%
  260     IF INKEY(-99) THEN SYS "GPIO_WriteData",10,1 ELSE SYS "GPIO_WriteData",10,0
  270     IF pin24% THEN PRINT "Open  ";:VDU 13 ELSE PRINT "Pushed";:VDU 13
  280   UNTIL 0
  290 ELSE
  300   PRINT "GPIO module not present"
  310 ENDIF
  320 END

   30 REM Test for Serial Support in ROM
   40 serial%=TRUE
   50 LOCAL ERROR
   60 ON ERROR LOCAL serial%=FALSE
   70 IF serial%=TRUE THEN OSCLI("RMEnsure SerialDeviceSupport 0.00 Error 6,This app requires Serial support")
   80 RESTORE ERROR
   90 :
  100 REM Set up serial port
  110 IF serial%=TRUE THEN
  120   SYS "OS_SerialOp",5,7,0:REM Baud rate to 9600
  130   SYS "OS_SerialOp",1,0:REM Set 8bit, 1 stop bit, no parity
  140   SYS "OS_SerialOp",0,&3E:REM Set no handshaking
  150   SYS "OS_Byte",2,2:REM Enable serial input buffer/kbd input
  160 ENDIF
  170 :
  180 REM Read a few characters from serial port
  190 IF serial%=TRUE THEN
  200   a$="":if%=0
  210   REPEAT
  220     SYS "OS_SerialOp",4,-1 TO ,r1% ;rf%
  230     if%+=1
  240     IF (rf% AND 2)=0 THEN
  250       REM Character in buffer (C clear)
  260       IF r1%<>0 AND r1%<>-1 THEN a$+=CHR$(r1%)
  270       REM IF r1%=0 OR r1%=-1 THEN "Odd serial error"
  280     ENDIF
  290   UNTIL (rf% AND 2) OR if%>20:REM Buffer empty or 20 attempts
  300 ENDIF

There is source available and is tagged as version 0.63.

Just downloaded version 0.60 (25-Feb-2015) from http://www.tankstage.co.uk/Software/ to test on a model A+ (which returns board revision &15) this CVS log indicates it should work but it does not work, saying board not recognised and pin state ‘invalid’ i.e. -1 from SYS “GPIO_ReadMode”. Any suggestions please?

Seem to have answered my own question again! Since 12 Feb 2017, version 1.00 of the GPIO module is in the source tarballs. After including GPIO version 1.00 in the rom build, I found it worked fine on the model A+.