Adjust-click on iconbar items

Please could Adjust-clicking the Task Manager (“switcher”) on the iconbar open the “Configure” window? At present, Adjust does exactly the same as Select, which is a waste.
    Ro6 has had this little enhancement for a long time; would it be difficult to add it to 5.21 and the forthcoming release of 5.22?

Or perhaps to open a more complete window, with open files, list of modules, etc.

Jim Nagel… Jim Nagel… Oh, Computer Shopper! Hi! Nice to see you here. [I know you’ve been here longer that I have, but you don’t post much. :-) ]

Please could Adjust-clicking the Task Manager (“switcher”) on the iconbar open the “Configure” window?

That is, actually, a really good idea.

Done.

You will need to find somebody that can build you a ROM image, until this is integrated into the main ROM build. For those who want to try this…

In …castle.RiscOS.Sources.Desktop.Switcher.s.Switcher, line 4332 says:

click_select
click_adjust
        LDR     R0,[R1,#b_window]

        LDR     R14,h_powerdown         ; was it the power down dialogue
        TEQ     R0,R14
        BEQ     power_click

        LDR     R14,h_shutdown          ; click in restart dialogue?
        TEQ     R0,R14
        BEQ     restart

        LDR     R14,h_savedbox
        TEQ     R0,R14
        BEQ     dbox_click

        LDR     R14,h_switcher          ; click in task window?
        TEQ     R0,R14                  ; no => assume iconbar icon
        BEQ     switcher_click

        CMP     R0,#iconbar_whandle
        BEQ     openswitcher
        Pull    "PC"                    ; ignore it if none of these

Change this to be:

click_select
        LDR     R0,[R1,#b_window]

        LDR     R14,h_powerdown         ; was it the power down dialogue
        TEQ     R0,R14
        BEQ     power_click

        LDR     R14,h_shutdown          ; click in restart dialogue?
        TEQ     R0,R14
        BEQ     restart

        LDR     R14,h_savedbox
        TEQ     R0,R14
        BEQ     dbox_click

        LDR     R14,h_switcher          ; click in task window?
        TEQ     R0,R14                  ; no => assume iconbar icon
        BEQ     switcher_click

        CMP     R0,#iconbar_whandle
        BEQ     openswitcher
        Pull    "PC"                    ; ignore it if none of these

click_adjust
        LDR     R0,[R1,#b_window]

        LDR     R14,h_powerdown         ; was it the power down dialogue
        TEQ     R0,R14
        BEQ     power_click

        LDR     R14,h_shutdown          ; click in restart dialogue?
        TEQ     R0,R14
        BEQ     restart

        LDR     R14,h_savedbox
        TEQ     R0,R14
        BEQ     dbox_click

        LDR     R14,h_switcher          ; click in task window?
        TEQ     R0,R14                  ; no => assume iconbar icon
        BEQ     switcher_click

        CMP     R0,#iconbar_whandle
        BEQ     goconfig
        Pull    "PC"                    ; ignore it if none of these

The difference is the adjust copy goes to “goconfig” if it’s the icon bar that was clicked upon. The reason for the code duplication is that we use R14 to read what button was pressed (just above in mouse_click) and we then stamp all over R14 in our comparisons. So the quickest route to what we want is to just have two code paths that do mostly the same thing. No effect in code timing, requires 64 bytes extra. Not a hardship.

I’ll email this to the code submissions address.

I’m running this here, just rebuilt my ROM, and… yeah… It’s a nice tweak.

No effect in code timing, requires 64 bytes extra. Not a hardship.

Agreed, but how about this:

click_select
        LDR     R0,[R1,#b_window]
        CMP     R0,#iconbar_whandle
        BEQ     openswitcher
        BNE     click_common

click_adjust
        LDR     R0,[R1,#b_window]
        CMP     R0,#iconbar_whandle
        BEQ     goconfig

; it's not a click on the iconbar icon so try our windows
; for this we treat select and adjust click the same

click_common
        LDR     R14,h_powerdown         ; was it the power down dialogue
        TEQ     R0,R14
        BEQ     power_click

        LDR     R14,h_shutdown          ; click in restart dialogue?
        TEQ     R0,R14
        BEQ     restart

        LDR     R14,h_savedbox
        TEQ     R0,R14
        BEQ     dbox_click

        LDR     R14,h_switcher          ; click in task window?
        TEQ     R0,R14                  ; no => assume iconbar icon
        BEQ     switcher_click

        Pull    "PC"                    ; ignore it if none of these

You might even be able to push LDR R0,[R1,#b_window] further up so it only needs to be done once, but I haven’t checked that.

Agreed, but how about this:

Not bad. I missed that iconbar_handle was a constant and not loaded into R14. Just building a version with your mods now.

Built, copied, works just fine.

Don’t forget to mail your modifications to code@ ! :-)

Nitpicky pointless optimisation stuff → I’d be inclined to swap the select and adjust blocks around so the most common case (clicking Select) can fall through without the additional branch and the pipeline trashing that would occur on older ARM cores (without speculative execution).
Oh, and the comment by the final TEQ is no longer relevant.

This was discussed a while back in thread Ways to make life easier for new RISC OS users ,for anyone not wanting to load a new rom yet, I knocked up a module then as a quick demo of an adjust click on switcher to open !Configure feature