Broken module headers may erroneously report module as not being 32 bit compatible

The CheckHeader routine (https://www.riscosopen.org/viewer/view/castle/RiscOS/Sources/Kernel/s/ModHand?rev=4.11.2.13#l2153) reads:

CheckHeader ROUT
        Push   "R3, lr"
        LDR     R3, [R1, #Module_HC_Table]
        BL      %FT11
        LDR     R3, [R1, #Module_HelpStr]
        BL      %FT11
        LDR     R3, [R1, #Module_Title]
        BL      %FT11
        LDR     R3, [R1, #Module_Service]
        BL      %FT10
        LDR     R3, [R1, #Module_Die]
        BIC     R3, R3, #&80000000              ; ignore top-bit (means cannot be RMCleared)
        BL      %FT10
        LDR     R3, [R1, #Module_Init]
        TST     R3, #&80000000
        BLEQ    %FT10                           ; only check init offset if an unsqueezed module
 [ No26bitCode
; Need to go through extra checks to see that (a) we have a module
; flags table, and (b) it says that we're 32-bit
        LDR     R3, [R1, #Module_SWIChunk]
        TST     R3, #&FF000000
        TSTEQ   R3, #Module_SWIChunkSize-1
        BNE     %FT88
        LDR     R3, [R1, #Module_SWIEntry]
        BL      %FT20
        LDR     R3, [R1, #Module_NameTable]
        BL      %FT21
        LDR     R3, [R1, #Module_NameCode]
        BL      %FT20
        LDR     R3, [R1, #Module_MsgFile]
        BL      %FT20
        LDR     R3, [R1, #Module_FlagTable]
        BL      %FT20
        LDR     R3, [R1, R3]
        TST     R3, #ModuleFlag_32bit
        BEQ     %FT88
 ]
        CLRV
        Pull   "R3, PC"

10      TST     R3, #3
        BNE     %FT99
11      CMP     R3, R2
        MOVLO   PC, lr
99
        ADR     R0, ErrorBlock_BadRMHeaderField
      [ International
        BL      TranslateError
      |
        SETV
      ]
        Pull   "R3, PC"

 [ No26bitCode
20      TST     R3, #3
        BNE     %FT88
21      CMP     R3, R2
        MOVLO   PC, lr
88
        ADR     R0, ErrorBlock_RMNot32bit
      [ International
        MOV     R3, R4
        LDR     R4, [R1, #Module_Title]
        ADD     R4, R1, R4
        BL      TranslateError_UseR4
        MOV     R4, R3
      |
        SETV
      ]
        Pull   "R3, PC"
        MakeErrorBlock RMNot32bit
 ]

        MakeErrorBlock BadRMHeaderField

All of the newer tests go to %20, %21, or %88 which reports the not 32 bit error. This does not make sense if, say, the SWI chunk is incorrect. If you set the Init address to be not word aligned, RISC OS reports “Illegal header field in module”. If you set the SWI chunk or flags word to be an odd number, RISC OS reports “Module ‘xxxx’ is not 32-bit compatible” (which may be completely erroneous).

Demonstrated: http://www.youtube.com/watch?v=3s0St2vg01w

Given that a message for crappy rubbish module headers already exists, would it not be better to use that for cases when the module information is damaged and not necessarily a 26/32 issue?

Invalid information is permitted in the SWI fields for the 26-bit modules, which are listed as optional on page 1-210 of the RISC OS 3 Programmer’s Reference Manuals.

The SWI handler fields are optional and are only used if they contain valid values.

Given this, if it has an invalid SWI chunk then it’s probably a 26-bit module without SWIs.

Invalid information is permitted in the SWI fields for the 26-bit modules, which are listed as optional on page 1-210 of the RISC OS 3 Programmer’s Reference Manuals.

The SWI handler fields are optional and are only used if they contain valid values.

Given this, if it has an invalid SWI chunk then it’s probably a 26-bit module without SWIs.

The content of the RO3 PRM’s is of historic interest. Any modules written to conform with the more recent (15 year old?) guide that the fields need to exist, but may contain zeros, is the issue here.

I suppose that being accurate all modules written to match the “new” style header model should contain zeros in &18,&1C,&20,&24,&28,&2C while &30 contains zero or &01 depending on 26 or 32 bit status.

In terms of the OS, it should check as fully as is reasonably practicable and report an appropriate error.