Indirection bug fix

There is a bug with redirection which serial redirection exaggerates.

In Kernel.s.Oscli RemoveOscliCharJobs wants changing from

RemoveOscliCharJobs ROUT
     Push   "R0-R2, lr"
     LDR     R0, =ZeroPage
     LDRB    R1, [R0, #RedirectInHandle]
     CMP     R1, #0
     ASSERT  (ZeroPage :AND: 255) = 0
     STRNEB  R0, [R0, #RedirectInHandle]
   [ ZeroPage <> 0
     MOV     R0, #0
   ] 
     SWINE   XOS_Find
     LDR     R0, =ZeroPage ; May have got error (discarded)
     LDRB    R1, [R0, #RedirectOutHandle]
     CMP     R1, #0
     ASSERT  (ZeroPage :AND: 255) = 0
     STRNEB  R0, [R0, #RedirectOutHandle]
   [ ZeroPage <> 0
     MOV     R0, #0 ; May have got error (discarded)
   ]
     SWINE   XOS_Find
     MOV     R2, #0
     MOV     R0, #WrchV
     ADR     R1, RedirectWrch
     SWI     XOS_Release
     CLRV
     Pull   "R0-R2, PC"

to

RemoveOscliCharJobs ROUT
     Push   "R0-R2, lr"
     MOV     R2, #0
     MOV     R0, #WrchV
     ADR     R1, RedirectWrch
     SWI     XOS_Release
     LDR     R0, =ZeroPage
     LDRB    R1, [R0, #RedirectInHandle]
     CMP     R1, #0
     ASSERT  (ZeroPage :AND: 255) = 0
     STRNEB  R0, [R0, #RedirectInHandle]
   [ ZeroPage <> 0
     MOV     R0, #0
   ] 
     SWINE   XOS_Find
     LDR     R0, =ZeroPage ; May have got error (discarded)
     LDRB    R1, [R0, #RedirectOutHandle]
     CMP     R1, #0
     ASSERT  (ZeroPage :AND: 255) = 0
     STRNEB  R0, [R0, #RedirectOutHandle]
   [ ZeroPage <> 0
     MOV     R0, #0 ; May have got error (discarded)
   ]
     SWINE   XOS_Find
     CLRV
     Pull   "R0-R2, PC"

The problem is that the handles are set to 0 before the WrchV is released and the file handle is closed. If you do

*echo test { serial1#sleep;rts: }

the serial driver can be sleeping in the file close function and any writes to WrchV while it is sleeping use a 0 filehandle. In my fix – the second version – I have moved the release of the vector to before the file close.

Tested on an iyonix.