Serial port on Pi

With data continually being spammed on the RXDATA pins, the following program stiffs the machine when the SPACE bar is pressed. First it disables the GPS module (which has an enable pin connected to GPIO 22) so that the serial data stop. Then it sets TXDATA and RXDATA to GPIO use. Then it restores them to UART function and (unsuccessfully) kicks the serial port back into life by changing speed and reenables the GPS module to start serail data again. Nothing gets received. Press SPACE bar and it gives the serial port the same kick again but this time with a break as well (SerialOp 2) and it stiffs the machine.

Actually I don’t care about the hang, I just want lines 120 to 250 to get the serial port receiving data again…

   10 REM >SerTest
   20 :
   30 REM Need to disable GPS
   40 SYS "GPIO_WriteData",22,1:REM Set pin 22 to HIGH
   50 SYS "GPIO_WriteOE",22,0:REM set pin 22 to output
   51 SYS "GPIO_WriteData",22,0:REM Set pin 22 to LOW
   60 :
   70 REM Set TXDATA and RXDATA to GPIO use
   80 SYS "GPIO_ReadOE",15 TO pin15%
   90 SYS "GPIO_WriteData",15,0
  100 SYS "GPIO_WriteOE",15,0
  110 :
  120 SYS "GPIO_ReadOE",14 TO pin14%
  130 SYS "GPIO_WriteData",14,0
  140 SYS "GPIO_WriteOE",14,0
  150 :
  160 REM Now try to get serial port functioning again
  170 SYS "GPIO_WriteMode",14,5:REM UART
  180 SYS "GPIO_WriteMode",15,5:REM UART
  190 *fx21,1
  200 SYS "OS_SerialOp",5,3,0:REM Baud rate to slow
  210 SYS "OS_SerialOp",1,0:REM Set 8bit, 1 stop bit, no parity
  220 SYS "OS_SerialOp",0,&3E:REM Set no handshaking
  230 SYS "OS_Byte",2,2:REM Enable serial input buffer/kbd input
  240 *FX 21,1
  250 SYS "OS_SerialOp",5,7,0:REM Baud rate to 9600
  251 REM SYS "OS_SerialOp",2,20:REM Use at your peril!
  260 REM Need to reenable GPS
  270 SYS "GPIO_WriteData",22,1:REM Set pin 22 to HIGH
  280 SYS "GPIO_WriteOE",22,0:REM set pin 22 to output
  300 :
  310 REM Just any display serial data received
  320 midline%=0
  330 line$=""
  340 serstat%=0
  350 REPEAT
  360   REM Set serialOK% to FALSE IF zero or top bit set char recd
  370   serialOK%=TRUE
  380   REM Try to obtain (only) up to twenty characters in each poll
  390   if%=0
  400   REPEAT
  410     SYS "OS_SerialOp",4,-1 TO ,r1% ;r2%
  420     if%+=1
  430     IF (r2% AND 2)=0 THEN
  440       REM Character in buffer (C clear)
  450       IF midline%=TRUE THEN
  460         IF r1%=10 OR r1%=13 THEN
  470           CASE LEFT$(line$,6) OF
  480           WHEN "$GPRMC","$GPGGA","$GPGLL","$GPGSV"
  490             REM Test checksum, ignoring $ and *
  500             cs%=0
  510             ji%=2
  520             a%=ASC(MID$(line$,ji%))
  530             REPEAT
  540               cs%=cs% EOR a%
  550               ji%+=1
  560               a%=ASC(MID$(line$,ji%))
  570             UNTIL a%=ASC("*") OR ji%>=LEN(line$)
  580             IF MID$(line$,ji%+1,2)=RIGHT$("0"+STR$~(cs%),2) THEN
  590               REM checksum OK
  600               serstat%=(serstat% AND &F) OR 12
  610               PRINT line$
  620             ENDIF
  630           ENDCASE
  640           line$=""
  650           midline%=1
  660         ELSE
  670           IF r1%<>0 AND r1%<>-1 AND LEN(line$)<220 THEN line$+=CHR$(r1%)
  680           IF r1%=0 THEN serialOK%=FALSE:REM Zero character rec'd
  690           IF r1% AND &80 THEN serialOK%=FALSE:REM tbs recd
  700           REMIF r1%=-1 THEN ERROR 28,"Char present but -1 ret'd"
  710         ENDIF
  720       ELSE
  730         IF r1%=10 OR r1%=13 THEN
  740           midline%=1
  750         ELSE
  760           IF midline%=1 THEN
  770             line$=""
  780             IF r1%<>0 AND r1%<>-1 THEN line$=CHR$(r1%)
  790             IF r1%=0 THEN serialOK%=FALSE:REM Zero char rec'd."
  800             IF r1% AND &80 THEN serialOK%=FALSE:REM tbs recd
  810             REM IF r1%=-1 THEN ERROR 28,"Char but -1 returned."
  820             !tem%=3
  830             SYS "OS_Word",14,tem%
  840             linetime%=!tem%:REM 4 LSB of 5-byte time
  850             linetim%=tem%!4 AND &FF
  860             midline%=TRUE
  870           ENDIF
  880         ENDIF
  890       ENDIF
  900     ENDIF
  910   UNTIL (r2% AND 2) OR if%>100:REM Buffer empty or 100 attempts
  920 UNTIL serialOK%=FALSE OR INKEY(-99)
  930 PRINT "So far just ";line$
  940 REM Space bar pressed, try tweaking serial
  950 :
  960 serstat%=serstat% OR 16
  970 flag2$="NoSer"
  980 *FX 21,1
  990 SYS "OS_SerialOp",5,3,0:REM Baud rate to slow
 1000 SYS "OS_SerialOp",1,0:REM Set 8bit, 1 stop bit, no parity
 1010 SYS "OS_SerialOp",0,&3E:REM Set no handshaking
 1020 SYS "OS_Byte",2,2:REM Enable serial input buffer/kbd input
 1030 *FX 21,1
 1040 SYS "OS_SerialOp",5,7,0:REM Baud rate to 9600
 1050 SYS "OS_SerialOp",2,20:REM Send break
 1060 GOTO 350