RC15 GPIO does not load on certain PI B+

I have 4 PI B+ here they all are screen printed with :-
Raspberry Pi Model B+ V1.2
© Raspberry Pi 2014

I can take the same RC15 SDcard and the software works only in one
of the PIs the only difference between the PIs that I can see is
the 1 that works has a SAMSUNG chip in position U1.

The others have an ELPIDA B4432BBPA-1D-F 16290R10500 in U1

Just to add a bit of confusion I have a fifth PI B+ that has a slightly different
ELPIDA B4432BBPA-1D-F 16240R12400 in U1 and that works!

RISCOS loads fine on all of the PIs but on some of the Pis the GPIO module is not being loaded
I’m assuming that the PI is not being identified correctly?

How does the GPIO module identify the board it is working on?

Is there some software I can try to see what identity the boards I have here are reporting.

Out of interest I have tried the software in a PI3 and it works correctly.

Use !ScreenHelp from !Store to see what revision number your board is.

Alternatively use the code below which will produce output something like:

RUN
The computer type is recognised from the BCMSupport module.
Unique ID is  CC-21-A6-EB-27-B8.
Raspberry Pi model 1 A+ (256Mbytes) PCB revision 1 Sony (15)

It is the hex number in brackets that the HAL uses to identify which model of Pi is in use and thus how memory is arranged. If it doesn’t recognise the model revision, then the GPIO module in ROM remains dormant. The Zero W (9000C1) is not yet recognised for example.

   10DIM buf% 3000
   20a%=FNask(&10002,0,0,4)
   30IF a% THEN
   40  IF (!a%) AND 1<<23 THEN
   50    REM Revision is a bit field
   60    CASE ((!a%) AND &FF0)>>4 OF
   70    WHEN 0:a6$="Raspberry Pi model 1 A"
   80    WHEN 1:a6$="Raspberry Pi model 1 B"
   90    WHEN 2:a6$="Raspberry Pi model 1 A+"
  100    WHEN 3:a6$="Raspberry Pi model 1 B+"
  110    WHEN 4:a6$="Raspberry Pi model 2 B"
  120    WHEN 5:a6$="Raspberry Pi Alpha"
  130    WHEN 6:a6$="Raspberry Pi Compute Module"
  140    WHEN 7:a6$="Raspberry Pi unknown model"
  150    WHEN 8:a6$="Raspberry Pi model 3"
  160    WHEN 9:a6$="Raspberry Pi Zero"
  170    OTHERWISE:a6$="Raspberry Pi unknown model"
  180    ENDCASE
  190    CASE ((!a%) AND &700000)>>20 OF
  200    WHEN 0:a6$+=" (256Mbytes)"
  210    WHEN 1:a6$+=" (512Mbytes)"
  220    WHEN 2:a6$+=" (1024Mbytes)"
  230    ENDCASE
  240    a6$+=" PCB revision "+STR$((!a%) AND &F)
  250    IF (!a%) AND 3<<24 THEN a6$+=" [over-volted]"
  260    a6$+=" ("+STR$~(!a%)+")"
  270  ELSE
  280    CASE (!a%) AND &1F OF
  290    WHEN 2:a6$="Raspberry Pi model 1 B (256Mbytes) PCB revision 1 (02)"
  300    WHEN 3:a6$="Raspberry Pi model 1 B (256Mbytes) PCB revision 1 (03)"
  310    WHEN 4:a6$="Raspberry Pi model 1 B (256Mbytes) PCB revision 2 Sony (04)"
  320    WHEN 5:a6$="Raspberry Pi model 1 B (256Mbytes) PCB revision 2 Qisda (05)"
  330    WHEN 6:a6$="Raspberry Pi model 1 B (256Mbytes) PCB revision 2 Egoman (06)"
  340    WHEN 7:a6$="Raspberry Pi model 1 A (256Mbytes) PCB revision 2 Egoman (07)"
  350    WHEN 8:a6$="Raspberry Pi model 1 A (256Mbytes) PCB revision 2 Sony (08)"
  360    WHEN 9:a6$="Raspberry Pi model 1 A (256Mbytes) PCB revision 2 Qisda (09)"
  370    WHEN 13:a6$="Raspberry Pi model 1 B (512Mbytes) PCB revision 2 Egoman (0D)"
  380    WHEN 14:a6$="Raspberry Pi model 1 B (512Mbytes) PCB revision 2 Sony (0E)"
  390    WHEN 15:a6$="Raspberry Pi model 1 B (512Mbytes) PCB revision 2 Qisda (0F)"
  400    WHEN 16:a6$="Raspberry Pi model 1 B+ (512Mbytes) PCB revision 1 Sony (10)"
  410    WHEN 17:a6$="Raspberry Pi Compute Module (512Mbytes) PCB revision 2 Sony (11)"
  420    WHEN 18:a6$="Raspberry Pi model 1 A+ (256Mbytes) PCB revision 1 Sony (12)"
  430    WHEN 19:a6$="Raspberry Pi model 1 B+ (512Mbytes) PCB revision 1 Embest (13)"
  440    WHEN 20:a6$="Raspberry Pi Compute Module (512Mbytes) PCB revision 1 Sony (14)"
  450    WHEN 21:a6$="Raspberry Pi model 1 A+ (256Mbytes) PCB revision 1 Sony (15)"
  460    OTHERWISE:a6$="Raspberry Pi unknown type of model 1 ("+STR$~((!a%) AND &1F)+")"
  470    ENDCASE
  480    IF (!a%) AND 1<<24 THEN a6$+=" [over-volted]"
  490  ENDIF
  500  SYS "OS_ReadSysInfo",2 TO ,,,r3%,r4%
  510  q$="The computer type is recognised from the BCMSupport module.|M"
  520  PRINT q$
  530  q$=RIGHT$("0"+STR$~((r4%>>8) AND &FF),2)+"-"+RIGHT$("0"+STR$~(r4% AND &FF),2)+"-"+RIGHT$("0"+STR$~((r3%>>24) AND &FF),2)+"-"+RIGHT$("0"+STR$~((r3%>>16) AND &FF),2)+"-"+RIGHT$("0"+STR$~((r3%>>8) AND &FF),2)+"-"+RIGHT$("0"+STR$~(r3% AND &FF),2)
  540  q$="Unique ID is  "+q$+"."
  550  PRINT q$
  560ELSE
  570  REM Already tested via isitPi% on initialisation
  580  a6$="Error when seeking information."
  590  IF flag%=2 THEN a6$="This Raspberry Pi machine requires RISC OS & firmware from 26 Mar 2016 onwards to show detailed information."
  600  SYS "OS_ReadSysInfo",2 TO ,,,r3%,r4%
  610  q$="This Raspberry Pi computer did not respond correctly to the BCMSupport module when seeking detailed information.|M"
  620  PRINT q$
  630  q$=RIGHT$("0"+STR$~((r4%>>8) AND &FF),2)+"-"+RIGHT$("0"+STR$~(r4% AND &FF),2)+"-"+RIGHT$("0"+STR$~((r3%>>24) AND &FF),2)+"-"+RIGHT$("0"+STR$~((r3%>>16) AND &FF),2)+"-"+RIGHT$("0"+STR$~((r3%>>8) AND &FF),2)+"-"+RIGHT$("0"+STR$~(r3% AND &FF),2)
  640  q$="Unique ID is  "+q$+"."
  650  PRINT q$
  660ENDIF
  670PRINT a6$
  680END
  690:
  700DEFFNask(tag%,lrq%,req%,lrs%)
  710LOCAL ERROR
  720flag%=0
  730buf%!0=232  :REM Buffer size
  740buf%!4=0    :REM buffer request/response code
  750buf%!8=tag% :REM &40003 - Get physical display width height
  760buf%!12=lrs%:REM value buffer size
  770buf%!16=lrq%:REM value length
  780buf%!20=req%:REM send/rec value
  790buf%!24=0   :REM send/rec value
  800buf%!28=0:REM buffer end tag
  810ON ERROR LOCAL flag%=2
  820IF flag%=0 THEN SYS "XBCMSupport_SendTempPropertyBuffer",buf%,buf% TO ;flag%:IF (flag% AND 1)=0 THEN flag%=0
  830RESTORE ERROR
  840IF (flag% AND 1) OR flag%=2 THEN =0 ELSE =buf%+20

When I run the software I get :-

The B+ unit that work reports

The computer type is recognised from the BCMSupport module.|M

Unique ID is  5B-0C-A6-2D-27-B8.

Raspberry Pi model 1 B+ (512Mbytes) PCB revision 1 embest (13)

One of the units that don’t work reports as below:-

The computer type is recognised from the BCMSupport module.|M

Unique ID is  B3-BA-04-EB-27-B8.

Raspberry Pi model 1 B+ (512Mbytes) PCB revision 2 (900032)

If I issue a rmreinit GPIO on the unit that does not work I get
Unsupported hardware configuration

Many thanks.

Yes, it looks like 900032 is (yet another) new revision that is not yet on the list so the HAL can’t decide how memory is arranged for GPIO access…

Thanks for the information.

I can still use the boards in other projects so its not a problem here.

It’s interesting that it partly identifies the board as a Raspberry Pi model 1 B+ (512Mbytes)

Anyway thanks for your help

The BASIC code snippet and the !ScreenHelp identify the board type and revision in a bit wise manner whereas the HAL uses a list of revision numbers.

I think Pi zero W (9000c1) is also not handled. http://elinux.org/RPi_HardwareHistory has a list of ids

I downloaded today’s beta ROM and can confirm that the B+ (900032)
now appear to be working correctly.

Thanks to everyone.