Decision code

My Drawing handler is as follows:

DEF PROCDealWith_WindowRedraw(object,xo%,yo%)
PROCUtils_RedrawDrawfile(drawfile%,length%,xo%,yo%)
PROCUtils_GetRedrawRectangle(minx,miny,maxx,maxy)

and to force a redraw I’ve added (using info. Chris’s posting)..

The Drawfile displays correctly but then I get “illegal window handle”.

The syntax looks OK – can anyone verify please?

SYS “Wimp_ForceRedraw”,object,minx,miny,maxx,maxy

You’re passing the toolbox window object’s ID to Wimp_ForceRedraw but this needs to be the window object’s window handle. You can get the window handle by using WimpHandle% = FNWindow_GetWimpHandle(object%).

Also, you don’t need to call PROCUtils_GetRedrawRectangle() as you’re redrawing the entire drawfile. The Wimp will sort out any clipping that needs to be done.

You need a loop to call ‘deal with window redraw’ presume you have something like:

   10
   20
   30WHILE NOT(quit%)
   40  SYS "Wimp_Poll",mask%,block% TO reason%
   50  CASE reason% OF
   60  WHEN 1:
   70    PROCredraw
   80  ...
   90  ENDCASE
  100ENDWHILE
  110:
  120DEFPROCredraw
  130CASE !block% OF
  140WHEN window_handle_you_are_using%
  150  SYS "Wimp_RedrawWindow",,block% TO flag
  160  WHILE flag
  210    x1c%=block%!28-block%!4+block%!20
  220    y1c%=block%!32-block%!16+block%!24
  230    x2c%=block%!36-block%!4+block%!20
  240    y2c%=block%!40-block%!16+block%!24
  250    cx%=block%!4-block%!20
  260    cy%=block%!16-block%!24
  270    REM This specifies the window position on screen in OS units
  280    REM block%!4=screenXmin (L)
  290    REM block%!8=screenYmin (B)
  300    REM block%!12=screenXmax (R)
  310    REM block%!16=screenYmax (T)
  320    REM Also the offset in work area coords of the TL of this window
  330    REM block%!20=scrollX
  340    REM block%!24=-scrollY
  350    REM This specifies the area to be drawn
  360    REM block%!28=screenXmin (L)
  370    REM block%!32=screenYmin (B)
  380    REM block%!36=screenXmax (R)
  390    REM block%!40=screenYmax (T)
  400    REM This corresponds to work area coords
  410    REM TL scrollX,-scrollY
  420    REM
  430    REM Hence destination is BL,TR 28..40
  440    REM and source is TL 20,24
  450    REM These draw elements would start at ddReg%+&80+!(ddReg%+&84)
  460    REM if they were part of the Draw file in memory
  470    REM but are actually held at bufmd%=ddDraw% to ddEDraw%
  480    :
  500    REM Now render it
  510    !ddtran%=&10000*zoom
  520    ddtran%!4=0
  530    ddtran%!8=0
  540    ddtran%!12=&10000*zoom
  550    ddtran%!16=-(ddReg%!24)*zoom+256*cx%
  600    ddtran%!20=-(ddReg%!36)*zoom+256*cy%
  620    SYS "DrawFile_Render",0,bufmd%,ddEDraw%-bufmd%,ddtran%,block%+28
  680    :
  690    SYS "Wimp_GetRectangle",,block% TO flag
  700  ENDWHILE
  710ENDCASE
  730ENDPROC

You need a loop to call ‘deal with window redraw’ presume you have something like

He won’t, because we’re discussing AppBASIC here.

In the context of Richard’s example, PROCDealWith_WindowRedraw() is an AppBASIC event handler and so AppBASIC implements something like the following pseudo-code behind the scenes:

SYS "Wimp_RedrawWindow",,block% TO more%
WHILE more%
  xo% = block%!4 - block%!20
  yo% = block%!16 - block%!24

  PROCDealWith_WindowRedraw(object, xo%, yo%)

  SYS "Wimp_GetRectangle",,block% TO more%
ENDWHILE

This makes most of your example unnecessary, as the event handler is called once for each redraw rectangle.

There are also AppBASIC PROCs and FNs to do a lot of the standard window redraw calculations, by the look of it.

Thanks Fred – I’m sure I’m nearly there. I’ve got the object’s window handle with…

WimpHandle% = FNWindow_GetWimpHandle(object%) as you suggested.

Using… SYS “Wimp_ForceRedraw”,WimpHandle%,536,144,1864,2120

where the four integers are minx,miny,maxx,maxy (obtained with MouseInfo) running the app. displays the Drawfile but – what I get is not easy to describe – the right-half of the window appears to give what looks like an animation – presumably caused by ForceRedraw SWI refreshing the window with the same image. Alt-Break is only means of stopping it.

So that the app. knows what these values are, wouldn’t I still have to use…

PROCUtils_GetRedrawRectangle()

Using… SYS “Wimp_ForceRedraw”,WimpHandle%,536,144,1864,2120

where the four integers are minx,miny,maxx,maxy (obtained with MouseInfo) running the app. displays the Drawfile but

What kind of coordinates does MouseInfo return? I assume it’s screen coordinates but as you’re passing a window handle to Wimp_ForceRedraw the coordinates should be relative to the window. To pass screen coordinates to Wimp_ForceRedraw you need to use -1 for the window handle.

An easy way to find out which coordinates to supply is to add a button gadget that covers the area taken up by the drawfile. Then call Wimp_GetWindowState to find out where the window is, and PROCGadget_GetBBox to get the gadget’s bounding box. From that you can work out the screen area to pass to Wimp_ForceRedraw.

Here’s the code that I use in ExifEdit to force a redraw of the displayed jpeg.

REM ============================================================================
REM Redraw the icon holding the Jpeg image.
REM ============================================================================
DEF PROC_ForceRedraw
LOCAL MaxX%,MaxY%,MinX%,MinY%,WinX%,WinY%
  PROCWindow_GetWimpHandle(MainID%,WimpHandle%)
  Block%!0 = WimpHandle%
  SYS "Wimp_GetWindowState",,Block%
  WinX% = Block%!4
  WinY% = Block%!16
  PROCGadget_GetBBox(MainID%,&7,x%,y%,X%,Y%)
  MinX% = WinX% + x% + 4
  MinY% = WinY% + y% + 4
  MaxX% = WinX% + X% - 4
  MaxY% = WinY% + Y% - 4
  SYS "Wimp_ForceRedraw",-1,MinX%,MinY%,MaxX%,MaxY%
ENDPROC

Thanks for your useful posting Fred. I haven’t had time to test your ForceRedraw code but I will get back to the Forum later in the week and let you know what happens.

Incidentally MouseInfo displays mouse pointer info. in OS units.